待機注文用EA開発テンプレートの全体記述

//+------------------------------------------------------------------+
//|                                    Template For PendingOrder EA  |
//|                                                MQL5ssei          |
//|                                  https://mqlinvestmentlab.com/   |
//+------------------------------------------------------------------+
#property copyright "MQL5ssei"
#property link      "https://mqlinvestmentlab.com/"


// 注文関連
#include <OriginalTrade.mqh> // 注文関連機能を提供するファイルをインクルード
OriginalCTrade Trade; // 取引のための主要インスタンス
OriginalCPositions Positions; // ポジション管理のためのインスタンス

// 価格情報
#include <OriginalPrice.mqh> // 価格データ取得のためのファイルをインクルード
OriginalCBars Price; // 価格情報を管理するインスタンス

// 資金管理
#include <OriginalMoneyManagement.mqh> // 資金管理機能を提供するファイルをインクルード

// トレーリングストップ
#include <OriginalTrailingStop.mqh> // トレーリングストップ機能を提供するファイルをインクルード
OriginalCTrailing Trailing; // トレーリングストップを管理するインスタンス

// インジケータ
#include <OriginalIndicators.mqh> // インジケータを扱うためのファイルをインクルード

// タイマー
#include <OriginalTimer.mqh> // タイマー機能を提供するファイルをインクルード
CTradeSession Session; // トレーディングセッションを管理するインスタンス
OriginalCNewBar NewBar; // 新しいバーが生成されたかを検出するインスタンス

// ペンディング注文関連のクラスをインクルード
#include <OriginalCpending.mqh>
OriginalCpending Pending; //ペンディング注文関連の情報を扱うインスタンス


//+------------------------------------------------------------------+
//| Input変数                                                         |
//+------------------------------------------------------------------+
input group "基本取引設定"  // 基本取引設定のグループ化
input ulong Slippage = 3;              // スリッページ設定
input ulong MagicNumber = 123;         // EA識別番号
input bool TradeOnNewBar = true;       // 新しいバーでの取引を行うかどうか

input group "資金管理"                  // 資金管理設定のグループ化
input bool UseMoneyManagement = false;  // マネーマネジメントを使用するかどうか
input double RiskPercent = 2;          // リスク許容度（％）
input double FixedVolume = 0.1;        // 固定取引量

input group "ストップロスとテイクプロフィット"  // ストップロスとテイクプロフィット設定のグループ化
input int StopLoss = 0;                // ストップロスの設定値
input int TakeProfit = 0;              // テイクプロフィットの設定値

input group "トレーリングストップ"            // トレーリングストップ設定のグループ化
input bool UseTrailingStop = false;    // トレーリングストップを使用するかどうか
input int TrailingStop = 500;            // トレーリングストップの距離
input int MinimumProfit = 200;           // トレーリングを開始する最小利益
input int Step = 20;                    // トレーリングのステップ

input group "ブレイクイーブン"              // ブレイクイーブン設定のグループ化
input bool UseBreakEven = false;       // ブレイクイーブンを使用するかどうか
input int BreakEvenProfit = 300;         // ブレイクイーブンに設定する利益
input int LockProfit = 0;              // 利益を確保するためのロック量

input group "トレードタイマー"              // トレードタイマー設定のグループ化
input bool UseTimer = false;           // トレードタイマーを使用するかどうか
input int StartHour = 0;               // トレード開始時間（時）
input int StartMinute = 0;             // トレード開始時間（分）
input int EndHour = 0;                 // トレード終了時間（時）
input int EndMinute = 0;               // トレード終了時間（分）
input bool UseLocalTime = false;       //ローカル時間を使うかどうか

//+------------------------------------------------------------------+
//| グローバル変数                                                       |
//+------------------------------------------------------------------+

ulong glBuyTicket, glSellTicket;//ポジション番号を格納する変数
bool glBuyPlaced, glSellPlaced; // 買い注文と売り注文が配置されたかどうかを示すフラグ

//+------------------------------------------------------------------+
//| OnInit関数                                                        |
//+------------------------------------------------------------------+


int OnInit()
  {
// フィルポリシーを取得する
   ENUM_ORDER_TYPE_FILLING filltype = FillPolicy();

// EAのマジックナンバーを設定する
   Trade.SetMagicNumber(MagicNumber);

// 注文実行時の許容スリッページを設定する
   Trade.SetDeviation(Slippage);

// 取得したフィルポリシーを設定する
   Trade.SetFillType(filltype);

// 初期化が完了したことを示す（0 = 成功）
   return(0);
  }

//+------------------------------------------------------------------+
//| OnTick関数                                                        |
//+------------------------------------------------------------------+


void OnTick()
  {
// 新しいバーがあるかどうかの初期状態をtrueと仮定し、バーシフトを0に設定
   bool newBar = true;
   int barShift = 0;

// 新しいバーでの取引を行う場合の処理
   if(TradeOnNewBar == true)
     {
      // 現在のシンボルと期間で新しいバーが始まったかどうかをチェック
      newBar = NewBar.CheckNewBar(_Symbol,_Period);

      // 新しいバーが確認された場合、バーシフトを1に設定
      barShift = 1;
     }

// トレードタイマーの設定
   bool timerOn = true;
// トレードタイマーを使用する場合の処理
   if(UseTimer == true)
     {
      // 指定された時間内で取引が許可されているかどうかをチェック
      timerOn = Session.DailySessionTimer(StartHour, StartMinute, EndHour, EndMinute, UseLocalTime);
     }

//価格情報をアップデートする
   Price.Update(_Symbol,_Period);

// 注文関連の記述
// 新しいバーかつトレードタイマーが許可している時のみ注文処理を行う
   if(newBar == true && timerOn == true)
     {
      // ロット調整
      double tradeSize;
      //資金管理モードONなら設定したリスクに応じたロットを算出
      if(UseMoneyManagement == true)
         tradeSize = MoneyRiskManagement(_Symbol,FixedVolume,RiskPercent,StopLoss);

      //固定ロットを指定
      else
         tradeSize = VerifyVolume(_Symbol,FixedVolume);

      // 買い注文について
      if(Positions.GetBuyPosCount(MagicNumber) == 0 // 買いポジションがない場合
         &&
         Pending.BuyLimitNum(_Symbol) == 0 // 買いリミット注文がない場合
         &&
         Pending.BuyStopNum(_Symbol) == 0 // 買いストップ注文がない場合
         &&
         Pending.BuyStopLimitNum(_Symbol) == 0 // 買いストップリミット注文がない場合
        ) // 買いポジションがなく、買い待機注文もなければ
        {
         double orderPrice = 0; // 注文価格を格納する変数
         orderPrice =ModifyUpperStopLevel(_Symbol, orderPrice); // ストップロスの設定が有効かチェック
         double buyStop = CalBuySL(_Symbol, StopLoss, orderPrice); // ストップロス計算
         double buyProfit = CalBuyTP(_Symbol, TakeProfit, orderPrice); // テイクプロフィット計算

         glBuyPlaced=Trade.BuyStop(_Symbol, tradeSize, orderPrice, buyStop, buyProfit); // 買いストップ注文を配置

         

        }//買い注文記述の終わり

      // 売り注文について
      if(Positions.GetSellPosCount(MagicNumber) == 0 // 売りポジションがない場合
         &&
         Pending.SellLimitNum(_Symbol) == 0 // 売りリミット注文がない場合
         &&
         Pending.SellStopNum(_Symbol) == 0 // 売りストップ注文がない場合
         &&
         Pending.SellStopLimitNum(_Symbol) == 0 // 売りストップリミット注文がない場合
        ) // 売りポジションがなく、売り待機注文もなければ
        {
         double orderPrice = 0; // 注文価格を格納する変数
         orderPrice =ModifyLowerStopLevel(_Symbol, orderPrice); // ストップロスの設定が有効かチェック
         double sellStop = CalSellSL(_Symbol,StopLoss,orderPrice);// ストップロス計算
         double sellProfit = CalSellTP(_Symbol,TakeProfit,orderPrice);// テイクプロフィット計算
         glSellPlaced = Trade.SellStop(_Symbol, tradeSize, orderPrice, sellStop, sellProfit); // 売りストップ注文を配置

         
        }//売り注文の記述終わり

     }// 注文関連の記述終わり

// ポジション番号を取得
   ulong tickets[]; // チケット番号を格納するための配列
   Positions.GetTotalPosNum(MagicNumber, tickets); // 全ポジションのポジション番号を取得
   int numTickets = ArraySize(tickets); // 取得したポジションの数を格納

// トレーリングストップ処理
   if(UseTrailingStop == true && numTickets > 0) // トレーリングストップが有効かつオープンポジションが存在する場合
     {
      for(int i = 0; i < numTickets; i++) // オープンポジションの数だけループ
        {
         // 各ポジションに対してトレーリングストップ処理を適用
         Trailing.TrailingStop(tickets[i], TrailingStop, MinimumProfit, Step);
        }
     }//トレーリングストップ記述の終わり

// ブレイクイーブン処理　
   if(UseBreakEven == true && numTickets > 0) // ブレイクイーブンが有効かつオープンポジションが存在する場合
     {
      for(int i = 0; i < numTickets; i++) // オープンポジションの数だけループ
        {
         // 各ポジションに対してブレイクイーブン処理を適用
         Trailing.BreakEven(tickets[i], BreakEvenProfit, LockProfit);
        }
     } // ブレイクイーブン処理の終わり



  }//全体記述の終わり

//+------------------------------------------------------------------+