OnTester関数について解説した記事内↓にて、
OnTester関数を利用したサンプルコードも掲載しているのですが、同じ記事内で解説するには、ちょっと長くて複雑だったもので、別記事にして数回に分けて解説することにしました。
前回はグローバル領域での定義部分について解説しました↓
今回解説するのはオリジナル関数であるCheckForOpen関数についてです。この関数はサンプルコード内でポジションを開く条件を設定する役割を担っています。
今回解説記述は以下の箇所です。
void CheckForOpen(void)
{
MqlRates rt[2]; // 過去2つのローソク足データを格納するための配列
//--- 新しいバーの始めのみで取引する
if (CopyRates(_Symbol, _Period, 0, 2, rt) != 2)
{
Print("CopyRates of ", _Symbol, " failed, no history");
return;
}
//--- ティックボリュームを確認する
if (rt[1].tick_volume > 1)
return;
//--- 移動平均値を取得する
double ma[1]; // 移動平均値を格納する配列
if (CopyBuffer(IndicatorHandle, 0, 1, 1, ma) != 1)
{
Print("CopyBuffer from iMA failed, no data");
return;
}
//--- シグナルの存在を確認する
ENUM_ORDER_TYPE signal = WRONG_VALUE; // シグナルの種類
//--- ローソク足が移動平均より高く開き、低く閉じた場合のシグナル
if (rt[0].open > ma[0] && rt[0].close < ma[0])
signal = ORDER_TYPE_BUY; // 買いシグナル
else if (rt[0].open < ma[0] && rt[0].close > ma[0]) // ローソク足が移動平均より低く開き、高く閉じた場合のシグナル
signal = ORDER_TYPE_SELL; // 売りシグナル
//--- 追加の確認を行う
if (signal != WRONG_VALUE)
{
if (TerminalInfoInteger(TERMINAL_TRADE_ALLOWED) && Bars(_Symbol, _Period) > 100)
{
double price = SymbolInfoDouble(_Symbol, signal == ORDER_TYPE_SELL ? SYMBOL_BID : SYMBOL_ASK); // 取引価格を取得
trade.PositionOpen(_Symbol, signal, Lots, price, 0, 0); // ポジションを開く
}
}
}スポンサーリンク
CheckForOpen関数の解説その1
関数の概要
CheckForOpen関数は、新しい取引シグナルを検出し、条件が満たされた場合にポジションを開く役割を持っています。まず、関数の先頭部分で行われている処理について見ていきます。
MqlRates配列の定義
void CheckForOpen(void)
{
MqlRates rt[2]; // 過去2つのローソク足データを格納するための配列この部分では、過去2つのローソク足データを格納するためにMqlRates型の配列を定義しています。MqlRates構造体は、ローソク足の時間、開値、高値、安値、終値、ティックボリュームなどの情報を含む構造体です。
新しいバーの始めのみで取引する
//--- 新しいバーの始めのみで取引する
if (CopyRates(_Symbol, _Period, 0, 2, rt) != 2)
{
Print("CopyRates of ", _Symbol, " failed, no history");
return;
}この部分では、新しいバーの始めにのみ取引を行うために、CopyRates関数を使用して最新の2つのローソク足データを取得します。もしデータが取得できない場合は、エラーメッセージを出力し、関数を終了します。
ティックボリュームの確認
//--- ティックボリュームを確認する
if (rt[1].tick_volume > 1)
return;ここでは、最新のローソク足のティックボリュームを確認します。ティックボリュームが1を超える場合は、取引を行わずに関数を終了します。
移動平均値の取得
//--- 移動平均値を取得する
double ma[1]; // 移動平均値を格納する配列
if (CopyBuffer(IndicatorHandle, 0, 1, 1, ma) != 1)
{
Print("CopyBuffer from iMA failed, no data");
return;
}最後に、移動平均値を取得します。CopyBuffer関数を使用して、移動平均の最新値を取得し、配列に格納します。もしデータが取得できない場合は、エラーメッセージを出力し、関数を終了します。
このように、CheckForOpen関数の先頭部分では、取引に必要なデータを取得し、初期チェックを行っています。次のセクションでは、シグナルの確認とポジションを開く条件について解説します。
CheckForOpen関数の解説その2
このセクションでは、ポジションを開く条件を設定する関数であるCheckForOpen関数のシグナル確認部分について解説します。
シグナルの存在を確認する
//--- シグナルの存在を確認する
ENUM_ORDER_TYPE signal = WRONG_VALUE; // シグナルの種類まず、ENUM_ORDER_TYPE型の変数signalをWRONG_VALUEで初期化します。これは、現時点でシグナルが存在しないことを示します。
買いシグナルの確認
//--- ローソク足が移動平均より高く開き、低く閉じた場合のシグナル
if (rt[0].open > ma[0] && rt[0].close < ma[0])
signal = ORDER_TYPE_BUY; // 買いシグナル次に、最新のローソク足（rt[0]）の開値が移動平均値（ma[0]）より高く、終値が移動平均値より低い場合、これは買いシグナルとみなし、signal変数にORDER_TYPE_BUYを設定します。
売りシグナルの確認
else if (rt[0].open < ma[0] && rt[0].close > ma[0]) // ローソク足が移動平均より低く開き、高く閉じた場合のシグナル
signal = ORDER_TYPE_SELL; // 売りシグナル反対に、最新のローソク足の開値が移動平均値より低く、終値が移動平均値より高い場合、これは売りシグナルとみなし、signal変数にORDER_TYPE_SELLを設定します。
この部分では、最新のローソク足と移動平均値の関係を評価し、買いシグナルまたは売りシグナルを検出しています。
CheckForOpen関数の解説その3
このセクションでは、ポジションを開く条件を設定するCheckForOpen関数の最後の部分について解説します。
追加の確認を行う
//--- 追加の確認を行う
if (signal != WRONG_VALUE)
{
if (TerminalInfoInteger(TERMINAL_TRADE_ALLOWED) && Bars(_Symbol, _Period) > 100)
{
double price = SymbolInfoDouble(_Symbol, signal == ORDER_TYPE_SELL ? SYMBOL_BID : SYMBOL_ASK); // 取引価格を取得
trade.PositionOpen(_Symbol, signal, Lots, price, 0, 0); // ポジションを開く
}
}
}
シグナルの確認
まず、signal変数がWRONG_VALUEでないことを確認します。これは、適切なシグナル（買いまたは売り）が検出されたことを意味します。
if (signal != WRONG_VALUE)取引の許可と十分なデータの確認
次に、取引が許可されているか（TERMINAL_TRADE_ALLOWED）と、十分なバー（ローソク足）データがあるか（Bars(_Symbol, _Period) > 100）を確認します。このチェックにより、EAが適切に動作する環境が整っていることを確認します。
if (TerminalInfoInteger(TERMINAL_TRADE_ALLOWED) && Bars(_Symbol, _Period) > 100)取引価格の取得
ここで三項演算子を使用して、取引価格を取得します。
double price = SymbolInfoDouble(_Symbol, signal == ORDER_TYPE_SELL ? SYMBOL_BID : SYMBOL_ASK); // 取引価格を取得
三項演算子の解説
三項演算子（?:）は、条件に基づいて異なる値を返すために使用されます。以下のように書かれます。
condition ? value_if_true : value_if_falseこの場合、signalがORDER_TYPE_SELLであるかどうかが条件となります。
- 条件が真（true）の場合、SYMBOL_BIDが返されます。
- 条件が偽（false）の場合、SYMBOL_ASKが返されます。
具体的には、signalがORDER_TYPE_SELLの場合、売り価格（BID）を取得し、そうでない場合は買い価格（ASK）を取得します。
ポジションを開く
最後に、CTradeクラスのPositionOpenメソッドを使用してポジションを開きます。ここでは、シンボル、シグナルの種類（買いまたは売り）、ロット数、価格を指定しています。
※第5引数と第6引数の0はそれぞれストップロスとテイクプロフィットを表しています。要はここではストップロスもテイクプロフィットも設定していないという事です。
trade.PositionOpen(_Symbol, signal, Lots, price, 0, 0); // ポジションを開くまとめ
このセクションでは、検出されたシグナルに基づいてポジションを開く条件を設定する部分について解説しました。特に、三項演算子を使用して取引価格を取得する方法について詳しく説明しました。
次回はポジションを閉じる為の関数について解説していきます。
サンプルコードの全体記述
OnTester関数を利用したサンプルコードの全体記述は以下の通りです。
//-- 取引操作クラスをインクルードする
#include <Trade\Trade.mqh>
//--- EA入力パラメータ
input double Lots = 0.1; // ロット数（取引量）
input int Slippage = 10; // 許容されるスリッページ（価格変動幅）
input int MovingPeriod = 80; // 移動平均の期間
input int MovingShift = 6; // 移動平均のシフト値
//--- グローバル変数
int IndicatorHandle = 0; // インジケータのハンドル（識別子）
bool IsHedging = false; // ヘッジング口座フラグ
CTrade trade; // 取引操作クラスのインスタンス
//--- マジックナンバーの定義（識別子）
#define EA_MAGIC 18052018
//+------------------------------------------------------------------+
//| ポジションを開く条件を確認する |
//+------------------------------------------------------------------+
void CheckForOpen(void)
{
MqlRates rt[2]; // 過去2つのローソク足データを格納するための配列
//--- 新しいバーの始めのみで取引する
if (CopyRates(_Symbol, _Period, 0, 2, rt) != 2)
{
Print("CopyRates of ", _Symbol, " failed, no history");
return;
}
//--- ティックボリュームを確認する
if (rt[1].tick_volume > 1)
return;
//--- 移動平均値を取得する
double ma[1]; // 移動平均値を格納する配列
if (CopyBuffer(IndicatorHandle, 0, 1, 1, ma) != 1)
{
Print("CopyBuffer from iMA failed, no data");
return;
}
//--- シグナルの存在を確認する
ENUM_ORDER_TYPE signal = WRONG_VALUE; // シグナルの種類
//--- ローソク足が移動平均より高く開き、低く閉じた場合のシグナル
if (rt[0].open > ma[0] && rt[0].close < ma[0])
signal = ORDER_TYPE_BUY; // 買いシグナル
else if (rt[0].open < ma[0] && rt[0].close > ma[0]) // ローソク足が移動平均より低く開き、高く閉じた場合のシグナル
signal = ORDER_TYPE_SELL; // 売りシグナル
//--- 追加の確認を行う
if (signal != WRONG_VALUE)
{
if (TerminalInfoInteger(TERMINAL_TRADE_ALLOWED) && Bars(_Symbol, _Period) > 100)
{
double price = SymbolInfoDouble(_Symbol, signal == ORDER_TYPE_SELL ? SYMBOL_BID : SYMBOL_ASK); // 取引価格を取得
trade.PositionOpen(_Symbol, signal, Lots, price, 0, 0); // ポジションを開く
}
}
}
//+------------------------------------------------------------------+
//| ポジションを閉じる条件を確認する |
//+------------------------------------------------------------------+
void CheckForClose(void)
{
MqlRates rt[2]; // 過去2つのローソク足データを格納するための配列
//--- 新しいバーの始めのみで取引する
if (CopyRates(_Symbol, _Period, 0, 2, rt) != 2)
{
Print("CopyRates of ", _Symbol, " failed, no history");
return;
}
if (rt[1].tick_volume > 1)
return;
//--- 移動平均値を取得する
double ma[1]; // 移動平均値を格納する配列
if (CopyBuffer(IndicatorHandle, 0, 1, 1, ma) != 1)
{
Print("CopyBuffer from iMA failed, no data");
return;
}
//--- ポジションがすでに選択されているか確認する
bool signal = false;
long type = PositionGetInteger(POSITION_TYPE); // ポジションの種類を取得
//--- ショートポジションを決済する条件
if (type == (long)POSITION_TYPE_SELL && rt[0].open > ma[0] && rt[0].close < ma[0])
signal = true;
//--- ロングポジションを決済する条件
if (type == (long)POSITION_TYPE_BUY && rt[0].open < ma[0] && rt[0].close > ma[0])
signal = true;
//--- 追加の確認を行う
if (signal)
{
if (TerminalInfoInteger(TERMINAL_TRADE_ALLOWED) && Bars(_Symbol, _Period) > 100)
trade.PositionClose(_Symbol, Slippage); // ポジションを閉じる
}
}
//+------------------------------------------------------------------+
//| 口座タイプ（ネッティングまたはヘッジ）を考慮してポジションを選択する |
//+------------------------------------------------------------------+
bool SelectPosition()
{
bool res = false;
//--- ヘッジ口座のポジションを選択する
if (IsHedging)
{
uint total = PositionsTotal(); // 全ポジションの数を取得
for (uint i = 0; i < total; i++)
{
string position_symbol = PositionGetSymbol(i); // ポジションのシンボルを取得
if (_Symbol == position_symbol && EA_MAGIC == PositionGetInteger(POSITION_MAGIC))
{
res = true;
break;
}
}
}
//--- ネッティング口座のポジションを選択する
else
{
if (!PositionSelect(_Symbol))
return (false);
else
return (PositionGetInteger(POSITION_MAGIC) == EA_MAGIC); // マジックナンバーを確認
}
//--- 実行結果を返す
return (res);
}
//+------------------------------------------------------------------+
//| エキスパート初期化関数 |
//+------------------------------------------------------------------+
int OnInit(void)
{
//--- 取引タイプ（ネッティングまたはヘッジ）を設定する
IsHedging = ((ENUM_ACCOUNT_MARGIN_MODE)AccountInfoInteger(ACCOUNT_MARGIN_MODE) == ACCOUNT_MARGIN_MODE_RETAIL_HEDGING);
//--- 正しいポジション制御のために取引操作クラスのオブジェクトを初期化する
trade.SetExpertMagicNumber(EA_MAGIC); // マジックナンバーを設定
trade.SetMarginMode(); // 証拠金モードを設定
trade.SetTypeFillingBySymbol(Symbol());// シンボルに基づいた執行タイプを設定
trade.SetDeviationInPoints(Slippage); // 許容スリッページを設定
//--- 移動平均指標を作成する
IndicatorHandle = iMA(_Symbol, _Period, MovingPeriod, MovingShift, MODE_SMA, PRICE_CLOSE);
if (IndicatorHandle == INVALID_HANDLE)
{
printf("Error creating iMA indicator");
return (INIT_FAILED);
}
//--- 初期化成功を示す
return (INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| エキスパートティック関数 |
//+------------------------------------------------------------------+
void OnTick(void)
{
//--- ポジションが既に開かれている場合は、決済条件を確認する
if (SelectPosition())
CheckForClose();
//--- ポジションを開く条件を確認する
CheckForOpen();
}
//+------------------------------------------------------------------+
//| テスタ関数 |
//+------------------------------------------------------------------+
double OnTester()
{
//--- カスタム条件最適化の値（高いほど良い）
double ret = 0.0;
//--- 取引結果を配列に入れる
double array[];
double trades_volume;
GetTradeResultsToArray(array, trades_volume);
int trades = ArraySize(array);
//--- 10取引未満の場合、肯定的結果がないことをテストする
if (trades < 10)
return (0);
//--- 取引あたりの平均結果
double average_pl = 0;
for (int i = 0; i < ArraySize(array); i++)
average_pl += array[i];
average_pl /= trades;
//--- 単一テストモード用のメッセージを表示する
if (MQLInfoInteger(MQL_TESTER) && !MQLInfoInteger(MQL_OPTIMIZATION))
PrintFormat("%s: Trades=%d, Average profit=%.2f", __FUNCTION__, trades, average_pl);
//--- 利益グラフの線形回帰を計算する
double a, b, std_error;
double chart[];
if (!CalculateLinearRegression(array, chart, a, b))
return (0);
//--- 回帰直線からグラフの偏差の誤差を計算する
if (!CalculateStdError(chart, a, b, std_error))
return (0);
//--- 傾向偏差の標準偏差を計算する
ret = (std_error == 0.0) ? a * trades : a * trades / std_error;
//--- カスタム条件最適化値を返す
return (ret);
}
//+------------------------------------------------------------------+
//| 取引の利益/損失の配列を得る |
//+------------------------------------------------------------------+
bool GetTradeResultsToArray(double &pl_results[], double &volume)
{
//--- 完全な取引履歴をリクエストする
if (!HistorySelect(0, TimeCurrent()))
return (false);
uint total_deals = HistoryDealsTotal(); // 全取引の数を取得
volume = 0;
//--- 証拠金を持つ配列の初期サイズを、履歴の取引数で設定する
ArrayResize(pl_results, total_deals);
//--- 取引結果を修正する取引のカウンター - 利益または損失
int counter = 0;
ulong ticket_history_deal = 0;
//--- 全ての取引を見る
for (uint i = 0; i < total_deals; i++)
{
//--- 取引を選択する
if ((ticket_history_deal = HistoryDealGetTicket(i)) > 0)
{
ENUM_DEAL_ENTRY deal_entry = (ENUM_DEAL_ENTRY)HistoryDealGetInteger(ticket_history_deal, DEAL_ENTRY); // 取引のエントリタイプを取得
long deal_type = HistoryDealGetInteger(ticket_history_deal, DEAL_TYPE); // 取引のタイプを取得
double deal_profit = HistoryDealGetDouble(ticket_history_deal, DEAL_PROFIT); // 取引の利益を取得
double deal_volume = HistoryDealGetDouble(ticket_history_deal, DEAL_VOLUME); // 取引の量を取得
//--- 興味があるのは取引操作のみである
if ((deal_type != DEAL_TYPE_BUY) && (deal_type != DEAL_TYPE_SELL))
continue;
//--- 損益を固定する取引のみ
if (deal_entry != DEAL_ENTRY_IN)
{
//--- 取引結果を配列に書き込み、取引のカウンターを増やす
pl_results[counter] = deal_profit;
volume += deal_volume;
counter++;
}
}
}
//--- 配列の最終サイズを設定する
ArrayResize(pl_results, counter);
return (true);
}
//+------------------------------------------------------------------+
//| 線形回帰を計算する y=a*x+b |
//+------------------------------------------------------------------+
bool CalculateLinearRegression(double &change[], double &chartline[], double &a_coef, double &b_coef)
{
//--- データが十分か確認する
if (ArraySize(change) < 3)
return (false);
//--- 蓄積されたチャート配列を作成する
int N = ArraySize(change);
ArrayResize(chartline, N);
chartline[0] = change[0];
for (int i = 1; i < N; i++)
chartline[i] = chartline[i - 1] + change[i];
//--- 線形回帰を計算する
double x = 0, y = 0, x2 = 0, xy = 0;
for (int i = 0; i < N; i++)
{
x = x + i;
y = y + chartline[i];
xy = xy + i * chartline[i];
x2 = x2 + i * i;
}
a_coef = (N * xy - x * y) / (N * x2 - x * x); // 傾きaを計算する
b_coef = (y - a_coef * x) / N; // 切片bを計算する
//--- 成功を示す
return (true);
}
//+------------------------------------------------------------------+
//| 指定されたaとbの平均二乗偏差誤差を計算する |
//+------------------------------------------------------------------+
bool CalculateStdError(double &data[], double a_coef, double b_coef, double &std_err)
{
//--- 誤差の平方和
double error = 0;
int N = ArraySize(data);
if (N <= 2)
return (false);
for (int i = 0; i < N; i++)
error += MathPow(a_coef * i + b_coef - data[i], 2);
std_err = MathSqrt(error / (N - 2)); // 標準誤差を計算する
//--- 成功を示す
return (true);
}
コメント