【MQL5】すぐに使える、ライブラリーの利用方法

#property copyright "MQL5ssei"
#property link      "https://mqlinvestmentlab.com/"
#property strict 
//+-----------------------------

//ライブラリーから関数をインポート
#import "OriginalLibrary.ex5"

double GetProfitCurrencyPair();
void OpenBuyStop();

#import


void OnTick()
  {
      //ノーポジならインポートした関数に従った買い注文を出す
      if(OrdersTotal()==0)OpenBuyStop();
     
    //インポートした関数が出力する値を格納する変数を宣言 
    double profit=GetProfitCurrencyPair();
    
    //インポートした関数が出力する値のコメント表示
    Comment("損益：　 ",profit);
  
  }//void OnTick()
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//|                                              OriginalLibrary.mq5 |
//|                                                         MQL5ssei |
//|                                    https://mqlinvestmentlab.com/ |
//+------------------------------------------------------------------+
#property copyright "MQL5ssei"
#property link      "https://mqlinvestmentlab.com/"
#property version   "1.00"

//ライブラリー利用宣言
#property library

//標準ライブラリーのトレードファイルを使えるようにする
#include <Trade\Trade.mqh>

// CTradeクラスのオブジェクトを宣言
CTrade trade;


//損益を計算する関数のエクスポート
double GetProfitCurrencyPair()export
{
   //利益を格納する変数を宣言
   double profitThisCurrencyPair=0;
   
   //ポジションプールを古いほうから直近に向かってチェック
   for(int icounter=PositionsTotal()-1;icounter>=0;icounter--)
   {  
      //各ポジションの通貨ペア情報を変数に格納
      string CurrencyPair=PositionGetSymbol(icounter);
      
      //チャートの通貨ペア情報がポジションの通貨ペアと一致していたら
      if(_Symbol==CurrencyPair)
      {
         //各ポジションの損益情報を変数に格納
         double positionProfit=PositionGetDouble(POSITION_PROFIT);
         //各ポジションのスワップ情報を変数に格納
         double positionSwap=PositionGetDouble(POSITION_SWAP);
         
         //ポジション毎の損益とスワップを合計し、積算していく
         profitThisCurrencyPair+=positionProfit +positionSwap;
      }//if(_Symbol==CurrencyPair)
      
   }//for(int icounter=PositionsTotal()-1;icounter>=0;i--)
   
   //正規化
   profitThisCurrencyPair=NormalizeDouble(profitThisCurrencyPair,2);
   
   //損益を戻り値として返す
   return profitThisCurrencyPair;
   
   
}//double GetProfitCurrencyPair()export


//+------------------------------------------------------------------+
//ストップオーダー関数のエクスポート
void OpenBuyStop() export
{
   //現在値（買い）情報の取得と正規化
   double Ask=NormalizeDouble(SymbolInfoDouble(_Symbol,SYMBOL_ASK),_Digits);
   
   //残高情報を取得
   double balance=AccountInfoDouble(ACCOUNT_BALANCE);
   
   //有効証拠金情報を取得
   double equity=AccountInfoDouble(ACCOUNT_EQUITY);
   
   if(equity==balance)//残高と有効証拠金が同じなら
   {
      trade.BuyStop(0.01,Ask+100*_Point,NULL,Ask-200*_Point,Ask+200*_Point,ORDER_TIME_GTC);
   }//if(equity==balance)
   

}//void OpenBuyStop() export
//+------------------------------------------------------------------+