【超入門】MQL5　ＥＡ講座　第120回「トレードタイマークラスを実装する-その2-」【EAの作り方】

class CTradeSession
{
public:
    // 取引セッションがアクティブかどうかをチェックする関数
    bool IsActive(datetime openTime, datetime closeTime, bool useLocalTime = false);
};

class CTradeSession
  {
private:
   //トレード開始時間と終了時間を格納する
   datetime          SessionStartTime, SessionEndTime;


public:
   // 取引セッションがアクティブかどうかをチェックする関数
   bool              IsActive(datetime openTime, datetime closeTime, bool useLocalTime = false);
   //毎日のトレードタイマーを作成する関数
   bool              DailySessionTimer(int parStartHour, int parStartMinute, int parEndHour, int parEndMinute, bool parLocalTime = false);
  };

//毎日のトレードタイマーを作成する関数
   bool DailySessionTimer(int parStartHour,
 　　　　　　　　　　　　　　int parStartMinute, 
　　　　　　　　　　　　　　 int parEndHour,
 　　　　                  int parEndMinute, 
                          bool parLocalTime = false);

bool CTradeSession::DailySessionTimer(int parStartHour, int parStartMinute, int parEndHour, int parEndMinute, bool parLocalTime=false)
{
    // 現在の時間を取得
    datetime currentTime;
    if(parLocalTime == true)
        currentTime = TimeLocal(); // ローカル時間を使用
    else
        currentTime = TimeCurrent(); // サーバー時間を使用

    // セッションの開始時間を設定
    SessionStartTime = GenerateTimestamp(parStartHour,parStartMinute);

    // セッションの終了時間を設定
    SessionEndTime = GenerateTimestamp(parEndHour,parEndMinute);

    // セッションの終了時間が開始時間より前に設定されている場合、終了時間を次の日に設定
    if(SessionEndTime <= SessionStartTime) 
    {
        SessionStartTime -= DAYS_TO_SECONDS; // 開始時間を一日分マイナス

        // 現在時刻が終了時間を過ぎていた場合、開始時間と終了時間を次の日にずらす
        if(currentTime > SessionEndTime)
        {
            SessionStartTime += DAYS_TO_SECONDS;
            SessionEndTime += DAYS_TO_SECONDS;
        }
    }

    // セッションがアクティブかどうかを判断
    bool timerOn = IsActive(SessionStartTime, SessionEndTime, parLocalTime);

    // タイマーの状態を出力
    Print(timerOn);

    // タイマーがオンかオフかの状態を返す
    return(timerOn);
}

// 現在の時間を取得
    datetime currentTime;
    if(parLocalTime == true)
        currentTime = TimeLocal(); // ローカル時間を使用
    else
        currentTime = TimeCurrent(); // サーバー時間を使用

  // セッションの開始時間を設定
    SessionStartTime = GenerateTimestamp(parStartHour,parStartMinute);

    // セッションの終了時間を設定
    SessionEndTime = GenerateTimestamp(parEndHour,parEndMinute);

// セッションの終了時間が開始時間より前に設定されている場合、終了時間を調整する
    if(SessionEndTime <= SessionStartTime) 
    {
        SessionStartTime -= DAYS_TO_SECONDS; // 開始時間を一日分マイナス

        // 現在時刻が終了時間を過ぎていた場合、開始時間と終了時間を次の日にずらす
        if(currentTime > SessionEndTime)
        {
            SessionStartTime += DAYS_TO_SECONDS;
            SessionEndTime += DAYS_TO_SECONDS;
        }
    }

   // セッションがアクティブかどうかを判断
    bool timerOn = IsActive(SessionStartTime, SessionEndTime, parLocalTime);

    // タイマーの状態を出力
    Print(timerOn);

    // タイマーがオンかオフかの状態を返す
    return(timerOn);

//+------------------------------------------------------------------+
//|                                       IsActive_Test.mq5          |
//|                 ティックデータに応じて処理を実行するためのコード  |
//|                                                                  |
//+------------------------------------------------------------------+

// OriginalTimer.mqhファイルをインクルード（事前定義された時間変換定数やクラスが含まれる）
#include <OriginalTimer.mqh>

// CTradeSessionクラスのインスタンスを生成（取引セッションを管理する）
CTradeSession TradeTimer;

// 入力パラメータの設定（外部から変更可能な変数）
input bool ActivateTimer=false;          // タイマーをアクティブにするかどうか
input int TradeStartHour=20;             // 取引開始時
input int TradeStartMinute=0;            // 取引開始分
input int TradeEndtHour=8;               // 取引終了時
input int TradeEndtMinute=0;             // 取引終了分
input bool ActivateLocalTimer=false;     // ローカルタイムをアクティブにするかどうか

// 新しいティックデータが来たときに実行される関数
void OnTick()
  {
   bool TradeOn=true;

   if(ActivateTimer==true)
     {


      // 現在の時刻が取引時間内かどうかをチェック（取引可能時間かを確認）
      TradeOn=
         TradeTimer.DailySessionTimer(TradeStartHour,TradeStartMinute,TradeEndtHour,TradeEndtMinute,ActivateLocalTimer);
     }

// 取引時間内であれば
   if(TradeOn==true)
     {
      // 注文を発注する処理をここに書く（取引時間内なら注文を出す）
     }
  }
//+------------------------------------------------------------------+

// OriginalTimer.mqhファイルをインクルード
#include <OriginalTimer.mqh>

// CTradeSessionクラスのインスタンスを生成
CTradeSession TradeTimer;

// 入力パラメータの設定（外部から変更可能な変数）
input bool ActivateTimer=false;          // タイマーをアクティブにするかどうか
input int TradeStartHour=20;             // 取引開始時
input int TradeStartMinute=0;            // 取引開始分
input int TradeEndtHour=8;               // 取引終了時
input int TradeEndtMinute=0;             // 取引終了分
input bool ActivateLocalTimer=false;     // ローカルタイムをアクティブにするかどうか

// 新しいティックデータが来たときに実行される関数
void OnTick()
  {
   bool TradeOn=true;// 取引が可能かどうかを管理するフラグ。初期値はtrue

   if(ActivateTimer==true)// もしタイマーをアクティブにする設定なら
     {


      // 現在の時刻が取引時間内かどうかをチェック（取引可能時間かを確認）
      TradeOn=
         TradeTimer.DailySessionTimer(TradeStartHour,TradeStartMinute,TradeEndtHour,TradeEndtMinute,ActivateLocalTimer);
     }

// 取引時間内であれば
   if(TradeOn==true)
     {
      // 注文を発注する処理をここに書く（取引時間内なら注文を出す）
     }
  }
//+------------------------------------------------------------------+

//+------------------------------------------------------------------+
//|                                                OriginalTimer.mqh |
//|                                                                  |
//|                                                                  |
//+------------------------------------------------------------------+

#define MINUTES_TO_SECONDS 60 // 1分を秒に変換する定数（60秒）
#define HOURS_TO_SECONDS 3600 // 1時間を秒に変換する定数（3600秒）
#define DAYS_TO_SECONDS 86400 // 1日を秒に変換する定数（86400秒）
#define WEEKS_TO_SECONDS 604800 // 1週間を秒に変換する定数（604800秒）



//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class OriginalCNewBar
  {
private:
   datetime TimeArray[], //現在の時間を格納
            LastTimeVar;//直近にチェックした時間

public:

   void              OriginalCNewBar();//配列「TimeArray」に時系列セットを施すコンストラクタ
   //新しいバーがオープンした瞬間かどうかをチェックする
   bool              CheckNewBar(string parSymbol, ENUM_TIMEFRAMES parTimeframe);
  };
//+------------------------------------------------------------------+

//コンストラクタOriginalCNewBarの処理実装記述
void OriginalCNewBar::OriginalCNewBar(void)
  {
   ArraySetAsSeries(TimeArray,true);//配列「TimeArray」を時系列にセットする
  }

// 新しいバーがオープンしたかどうかをチェックするメンバ関数の実装
bool OriginalCNewBar::CheckNewBar(string parSymbol, ENUM_TIMEFRAMES parTimeframe)
  {
// 初回実行かどうかを判定するフラグ
   bool firstExe = false;
// 新しいバーがオープンしたかどうかを示すフラグ
   bool newBarOpen = false;

// 指定されたシンボルと時間枠の現在と一つ前のバーの時間をTimeArrayにコピー
   CopyTime(parSymbol, parTimeframe, 0, 2, TimeArray);

// LastTimeVarが0の場合、これが初回実行と判断
   if(LastTimeVar == 0)
      firstExe = true;

// TimeArrayの最新の時間がLastTimeVarより大きい場合、新しいバーと判断
   if(TimeArray[0] > LastTimeVar)
     {
      // 初回実行ではない場合、newBarフラグをtrueに設定
      if(firstExe == false)
         newBarOpen = true;
      // 最後にチェックしたバーのオープン時間を更新
      LastTimeVar = TimeArray[0];
     }

// 新しいバーの有無を返す
   return(newBarOpen);
  }


// 日付時間値を生成する関数
datetime GenerateTimestamp(int newHour = 0, int newMinute = 0)
  {
   MqlDateTime dateTimeDetails; // MqlDateTime構造体を使用して日時データを保存するための変数
   TimeToStruct(TimeCurrent(), dateTimeDetails); // 現在のサーバーの時間を取得し、dateTimeDetails構造体に代入

   dateTimeDetails.hour = newHour; // 時間を新しい値に設定
   dateTimeDetails.min = newMinute; // 分を新しい値に設定

   datetime constructedTime = StructToTime(dateTimeDetails); // MqlDateTime構造体値をdatetime値に変換

   return(constructedTime); // 変換したdatetime値を返す
  }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CTradeSession
  {
private:
   //トレード開始時間と終了時間を格納する
   datetime          SessionStartTime, SessionEndTime;


public:
   // 取引セッションがアクティブかどうかをチェックする関数
   bool              IsActive(datetime openTime, datetime closeTime, bool useLocalTime = false);
   //毎日のトレードタイマーを作成する関数
   bool DailySessionTimer(int parStartHour, int parStartMinute, int parEndHour, int parEndMinute, bool parLocalTime = false);
  };

// 取引セッションがアクティブかどうかをチェックする関数の実装
bool CTradeSession::IsActive(datetime openTime, datetime closeTime, bool useLocalTime = false)
  {
// 開始時間が終了時間より後であるかどうかを確認
   if(openTime >= closeTime)
     {
      // 開始時間と終了時間が不正である場合、警告メッセージを出力して処理を中止
      Alert("エラー：開始時間または終了時間が不正です");
      return false; // 不正な時間設定のため、falseを返す
     }

// 現在時刻を取得する
   datetime currentTime;
//ローカル時間を使うかどうかのチェック
   if(useLocalTime == true)
      currentTime = TimeLocal();
   else
      currentTime = TimeCurrent();

// 現在時刻が開始時間と終了時間の範囲内かどうかをチェック
   bool timerOn = false; // タイマーがオンかどうかのフラグを初期化
   if(currentTime >= openTime && currentTime < closeTime)
     {
      // 現在時刻が指定された時間範囲内にある場合、タイマーをオンにする
      timerOn = true;
     }

   return timerOn; // タイマーの状態を返す
  }

// Daily timer
bool CTradeSession::DailySessionTimer(int parStartHour, int parStartMinute, int parEndHour, int parEndMinute, bool parLocalTime=false)
{
    // 現在の時間を取得
    datetime currentTime;
    if(parLocalTime == true)
        currentTime = TimeLocal(); // ローカル時間を使用
    else
        currentTime = TimeCurrent(); // サーバー時間を使用

    // セッションの開始時間を設定
    SessionStartTime = GenerateTimestamp(parStartHour,parStartMinute);

    // セッションの終了時間を設定
    SessionEndTime = GenerateTimestamp(parEndHour,parEndMinute);

    // セッションの終了時間が開始時間より前に設定されている場合、終了時間を調整する
    if(SessionEndTime <= SessionStartTime) 
    {
        SessionStartTime -= DAYS_TO_SECONDS; // 開始時間を1日分マイナスする

        // 現在時刻が終了時間を過ぎていた場合、開始時間と終了時間を次の日にずらす
        if(currentTime > SessionEndTime)
        {
            SessionStartTime += DAYS_TO_SECONDS;
            SessionEndTime += DAYS_TO_SECONDS;
        }
    }

    // セッションがアクティブかどうかを判断
    bool timerOn = IsActive(SessionStartTime, SessionEndTime, parLocalTime);

    // タイマーの状態を出力
    Print(timerOn);

    // タイマーがオンかオフかの状態を返す
    return(timerOn);
}

//+------------------------------------------------------------------+